configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([psensor], [1.1.0.x],[jeanfi@gmail.com],[psensor],[http://wpitchoune.net/psensor])
   6
   7 AM_INIT_AUTOMAKE([-Wall gnu])
   8
   9 AC_CONFIG_SRCDIR([src/ui.c])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 # m4
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 # Checks for programs.
  16 AC_PROG_CC
  17 AM_PROG_CC_C_O
  18
  19 AC_SYS_LARGEFILE
  20
  21 # Checks lib build
  22 AC_PROG_RANLIB
  23 AM_PROG_AR
  24
  25 # Checks for header files.
  26 AC_PATH_X
  27 AC_CHECK_HEADERS([stdbool.h])
  28
  29 # Checks for typedefs, structures, and compiler characteristics.
  30 AC_TYPE_SIZE_T
  31 AC_TYPE_SSIZE_T
  32
  33 # Checks for library functions.
  34 AC_FUNC_MALLOC
  35 AC_FUNC_REALLOC
  36 AC_CHECK_FUNCS([gettimeofday memmove socket strdup strtol])
  37
  38 AM_GNU_GETTEXT_VERSION([0.16])
  39 AM_GNU_GETTEXT([external])
  40
  41 # Gsettings
  42 GLIB_GSETTINGS
  43
  44 ############### common
  45
  46 # Checks pthread
  47 AC_CHECK_LIB(pthread, pthread_create)
  48 PTHREAD_LIBS=-pthread
  49 AC_SUBST(PTHREAD_LIBS)
  50
  51 # Checks sensors, required by psensor and psensor-server
  52 AC_CHECK_LIB(sensors, sensors_init)
  53 AC_CHECK_HEADERS([sensors/sensors.h sensors/error.h])
  54 SENSORS_LIBS=-lsensors
  55 AC_SUBST(SENSORS_LIBS)
  56
  57 ############### psensor
  58
  59 ### Required
  60
  61 PKG_CHECK_MODULES(X11, x11,,[AC_MSG_WARN("x11 missing psensor will not be built")])
  62 AM_CONDITIONAL(X11, test -n "$X11_LIBS")
  63 AC_SUBST(X11_CFLAGS)
  64 AC_SUBST(X11_LIBS)
  65
  66 PKG_CHECK_MODULES(XEXT, xext,,[AC_MSG_WARN("xext missing psensor will not be built")])
  67 AM_CONDITIONAL(XEXT, test -n "$XEXT_LIBS")
  68 AC_SUBST(XEXT_CFLAGS)
  69 AC_SUBST(XEXT_LIBS)
  70
  71 # Checks GTK+ 3.0
  72 PKG_CHECK_MODULES(GTK,
  73                   [gtk+-3.0 >= 3.4],,
  74                   [AC_MSG_WARN("gtk missing psensor will not be built")])
  75 AM_CONDITIONAL(GTK, test -n "$GTK_LIBS")
  76 # ensure that only allowed headers are included
  77 GTK_CFLAGS+=" -DGTK_DISABLE_SINGLE_INCLUDES "
  78 # ensure that no gtk deprecated symbols are used
  79 GTK_CFLAGS+=" -DGDK_DISABLE_DEPRECATED "
  80 GTK_CFLAGS+=" -DGTK_DISABLE_DEPRECATED "
  81 # ensure use of accessors
  82 GTK_CFLAGS+=" -DGSEAL_ENABLE "
  83 AC_SUBST(GTK_CFLAGS)
  84 AC_SUBST(GTK_LIBS)
  85
  86 # udisks2
  87
  88 PKG_CHECK_MODULES(LIBUDISKS2,
  89                   udisks2,
  90                   [AC_DEFINE([HAVE_LIBUDISKS2],[1],[Use libudisks])],
  91                   [AC_MSG_WARN("Library udisks2 not present")])
  92 AM_CONDITIONAL(LIBUDISKS2, test -n "$LIBUDISKS2_LIBS")
  93 AC_SUBST(LIBUDISKS2_CFLAGS)
  94 AC_SUBST(LIBUDISKS2_LIBS)
  95
  96 # check libatasmart
  97 PKG_CHECK_MODULES(ATASMART, libatasmart,
  98                   [AC_DEFINE([HAVE_ATASMART],[1],[Use libatasmart])],
  99                   [AC_MSG_WARN("Library atasmart not present")])
 100
 101 AM_CONDITIONAL(ATASMART, test -n "$ATASMART_LIBS")
 102 AC_SUBST(ATASMART_CFLAGS)
 103 AC_SUBST(ATASMART_LIBS)
 104
 105 # Check libnotify
 106 LIBNOTIFY_LIBS=
 107 PKG_CHECK_MODULES(LIBNOTIFY,
 108   libnotify,
 109   [AC_DEFINE([HAVE_LIBNOTIFY],[1],[Use desktop notification])],
 110   [AC_MSG_WARN("Desktop notification disabled")])
 111 AM_CONDITIONAL(LIBNOTIFY, test -n "$LIBNOTIFY_LIBS")
 112 AC_SUBST(LIBNOTIFY_CFLAGS)
 113 AC_SUBST(LIBNOTIFY_LIBS)
 114
 115 # Checks AppIndicator
 116 APPINDICATOR_LIBS=
 117
 118 PKG_CHECK_MODULES(APPINDICATOR, appindicator3-0.1,
 119      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator3-0.1])],
 120      [AC_MSG_WARN(AppIndicator 3-0.1 not present")])
 121
 122 if test "$APPINDICATOR_LIBS" == ""; then
 123    PKG_CHECK_MODULES(APPINDICATOR,
 124      appindicator-0.1 <= 0.2.9 ,
 125      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator 0.2.9])
 126       AC_DEFINE([HAVE_APPINDICATOR_029],[1],[Use AppIndicator 0.2.9])
 127      ],
 128      [AC_MSG_WARN(AppIndicator 0.2.9 not present")])
 129 fi
 130
 131 if test "$APPINDICATOR_LIBS" == ""; then
 132    PKG_CHECK_MODULES(APPINDICATOR,
 133      appindicator-0.1 > 0.2.9,
 134      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator > 0.2.9])],
 135      [AC_MSG_WARN("AppIndicator > 0.2.9 not present")])
 136 fi
 137 AM_CONDITIONAL(APPINDICATOR, test -n "$APPINDICATOR_LIBS")
 138 AC_SUBST(APPINDICATOR_CFLAGS)
 139 AC_SUBST(APPINDICATOR_LIBS)
 140
 141 # Check CURL, needed for remote monitoring
 142 CURL_LIBS=
 143 PKG_CHECK_MODULES(CURL,
 144   libcurl,
 145   [AC_DEFINE([HAVE_CURL],[1],[Use CURL])],
 146   [AC_MSG_WARN("Remote monitoring disabled, curl missing")])
 147 AM_CONDITIONAL(CURL, test -n "$CURL_LIBS")
 148 AC_SUBST(CURL_CFLAGS)
 149 AC_SUBST(CURL_LIBS)
 150
 151 # Check JSON, needed for remote monitoring
 152 JSON_LIBS=
 153 PKG_CHECK_MODULES(JSON,
 154                   json-c >= 0.11.99,
 155                   [AC_DEFINE([HAVE_JSON],[1],[Use JSON])],
 156                   [AC_MSG_WARN("json-c missing")])
 157
 158 if test "$JSON_LIBS" == ""; then
 159 PKG_CHECK_MODULES(JSON,
 160                   json >= 0.11.99,
 161                   [AC_DEFINE([HAVE_JSON],[1],[Use JSON])
 162                    AC_DEFINE([HAVE_JSON_0],[1],[Use JSON0])],
 163                   [AC_MSG_WARN("json0 missing")])
 164 fi
 165
 166 AM_CONDITIONAL(JSON, test -n "$JSON_LIBS")
 167 AC_SUBST(JSON_CFLAGS)
 168 AC_SUBST(JSON_LIBS)
 169
 170 # Enables remote monitoring if JSON and CURL is present
 171 if test -n "$JSON_LIBS"; then
 172    if test -n "$CURL_LIBS"; then
 173    AC_DEFINE([HAVE_REMOTE_SUPPORT],[1],[Remote monitoring enabled])
 174    fi
 175 fi
 176
 177 # Checks NVIDIA
 178 # following code from sensors-applet
 179 # sensors-applet.sourceforge.net/
 180 AC_CHECK_HEADERS(NVCtrl/NVCtrl.h NVCtrl/NVCtrlLib.h,
 181                  [ HAVE_NVIDIA=true ], [],
 182                  [
 183                   #include <X11/Xlib.h>
 184                  ])
 185 if test -n "${X11_LIBS}"; then
 186 LIBS="${LIBS} -lX11 -lXext"
 187
 188 if test "${HAVE_NVIDIA}" = "true"; then
 189   AC_CHECK_LIB(XNVCtrl,XNVCTRLQueryExtension,
 190                  [NVIDIA_LIBS="-lXNVCtrl -lX11 -lXext"
 191                   AC_DEFINE(HAVE_NVIDIA,1,[NVidia support enabled])
 192                  ])
 193 fi
 194 fi
 195 AM_CONDITIONAL(NVIDIA, test -n "$NVIDIA_LIBS")
 196 AC_SUBST(NVIDIA_CFLAGS)
 197 AC_SUBST(NVIDIA_LIBS)
 198
 199 # Checks Unity
 200 PKG_CHECK_MODULES(UNITY,
 201                   unity >= 3.4.2,
 202                   [AC_DEFINE([HAVE_UNITY],[1],[Use Unity])],
 203                   [AC_MSG_WARN(Unity not present)])
 204 AC_SUBST(UNITY_CFLAGS)
 205 AC_SUBST(UNITY_LIBS)
 206 AM_CONDITIONAL(UNITY, test -n "$UNITY_LIBS")
 207
 208 # libatiadl
 209 AC_ARG_WITH(libatiadl,
 210 [  --with-libatiadl[=DIR]   use libatiadlxx in DIR],[
 211                    ATIADL_DIR=${withval}
 212                    CPPFLAGS="${CPPFLAGS} -I${ATIADL_DIR}/include"
 213                    LIBS="$LIBS -L/usr/lib/fglrx -L/usr/lib64/fglrx -L/usr/lib/catalyst -L/usr/lib64/catalyst"
 214                   ]
 215 )
 216
 217 AC_CHECK_HEADERS(adl_defines.h,
 218         AC_CHECK_LIB(atiadlxx,ADL_Main_Control_Refresh,
 219                 [
 220                         AC_DEFINE(HAVE_LIBATIADL,1,[libatiadl is available])
 221                         LIBATIADL_CFLAGS="-I${ATIADL_DIR}/include"
 222                         LIBATIADL_LIBS="-L/usr/lib/fglrx -L/usr/lib64/fglrx -L/usr/lib/catalyst -L/usr/lib64/catalyst -latiadlxx -ldl"
 223                 ]))
 224
 225 AM_CONDITIONAL(LIBATIADL, test -n "$LIBATIADL_LIBS")
 226 AC_SUBST(LIBATIADL_CFLAGS)
 227 AC_SUBST(LIBATIADL_LIBS)
 228
 229 ############### psensor-server
 230
 231 # libmicrohttpd, mandatory for psensor-server
 232 LIBMICROHTTPD_LIBS=
 233 PKG_CHECK_MODULES(LIBMICROHTTPD,
 234   libmicrohttpd,
 235   [AC_DEFINE([HAVE_LIBMICROHTTPD],[1],[Use libmicrohttpd])],
 236   [AC_MSG_WARN("libmicrohttpd not present, psensor-server will NOT be built")])
 237 AM_CONDITIONAL(LIBMICROHTTPD, test -n "$LIBMICROHTTPD_LIBS")
 238 AC_SUBST(LIBMICROHTTPD_CFLAGS)
 239 AC_SUBST(LIBMICROHTTPD_LIBS)
 240
 241 # GTop, optional
 242
 243 AC_ARG_WITH(gtop,
 244 [  --with-gtop[=yes|no]   use gtop],[
 245         with_gtop=$withval],[
 246         with_gtop="yes"
 247 ])
 248
 249 GTOP_LIBS=
 250 if test "$with_gtop" = "yes"; then
 251 PKG_CHECK_MODULES(GTOP,
 252   libgtop-2.0,
 253   [AC_DEFINE([HAVE_GTOP],[1],[Use GTOP])],
 254   [AC_MSG_WARN("gtop not present, CPU/Memory information will NOT be available")])
 255 fi
 256 AM_CONDITIONAL(GTOP, test -n "$GTOP_LIBS")
 257 AC_SUBST(GTOP_CFLAGS)
 258 AC_SUBST(GTOP_LIBS)
 259
 260 AC_CONFIG_FILES([
 261  Makefile
 262  doc/Makefile
 263  src/Makefile
 264  src/glade/Makefile
 265  src/lib/Makefile
 266  src/server/Makefile
 267  icons/hicolor/scalable/Makefile
 268  icons/hicolor/14x14/Makefile
 269  icons/hicolor/16x16/Makefile
 270  icons/hicolor/22x22/Makefile
 271  icons/hicolor/24x24/Makefile
 272  icons/hicolor/32x32/Makefile
 273  icons/hicolor/48x48/Makefile
 274  icons/hicolor/64x64/Makefile
 275  icons/ubuntu-mono-dark/status/22/Makefile
 276  icons/ubuntu-mono-light/status/22/Makefile
 277  icons/ubuntu-mono-dark/apps/22/Makefile
 278  www/Makefile
 279  po/Makefile.in
 280  tests/Makefile
 281 ])
 282
 283 AC_CHECK_PROGS([HELP2MAN], [help2man])
 284
 285 AC_CHECK_PROG([ASCIIDOC], [asciidoc], yes)
 286 AM_CONDITIONAL(ASCIIDOC, test -n "$ASCIIDOC")
 287
 288 AC_CHECK_PROG(HAVE_CPPCHECK, cppcheck, yes)
 289 AM_CONDITIONAL(CPPCHECK, test -n "$HAVE_CPPCHECK")
 290
 291 AC_OUTPUT