configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.69])
   5 AC_INIT([psensor], [1.1.2],[jeanfi@gmail.com],[psensor],[http://wpitchoune.net/psensor])
   6
   7 AM_INIT_AUTOMAKE([-Wall gnu])
   8
   9 AC_CONFIG_SRCDIR([src/ui.c])
  10 AC_CONFIG_HEADERS([config.h])
  11
  12 # m4
  13 AC_CONFIG_MACRO_DIR([m4])
  14
  15 # Checks for programs.
  16 AC_PROG_CC
  17 AM_PROG_CC_C_O
  18
  19 AC_SYS_LARGEFILE
  20
  21 # Checks lib build
  22 AC_PROG_RANLIB
  23 AM_PROG_AR
  24
  25 # Checks for header files.
  26 AC_PATH_X
  27 AC_CHECK_HEADERS([stdbool.h])
  28
  29 AM_GNU_GETTEXT_VERSION([0.16])
  30 AM_GNU_GETTEXT([external])
  31
  32 # Gsettings
  33 GLIB_GSETTINGS
  34
  35 ############### common
  36
  37 # Checks pthread
  38 AC_CHECK_LIB(pthread, pthread_create)
  39 PTHREAD_LIBS=-pthread
  40 AC_SUBST(PTHREAD_LIBS)
  41
  42 # Checks sensors, required by psensor and psensor-server
  43 AC_CHECK_LIB(sensors, sensors_init)
  44 AC_CHECK_HEADERS([sensors/sensors.h sensors/error.h])
  45 SENSORS_LIBS=-lsensors
  46 AC_SUBST(SENSORS_LIBS)
  47
  48 ############### psensor
  49
  50 ### Required
  51
  52 PKG_CHECK_MODULES(X11, x11,,[AC_MSG_WARN("x11 missing psensor will not be built")])
  53 AM_CONDITIONAL(X11, test -n "$X11_LIBS")
  54 AC_SUBST(X11_CFLAGS)
  55 AC_SUBST(X11_LIBS)
  56
  57 PKG_CHECK_MODULES(XEXT, xext,,[AC_MSG_WARN("xext missing psensor will not be built")])
  58 AM_CONDITIONAL(XEXT, test -n "$XEXT_LIBS")
  59 AC_SUBST(XEXT_CFLAGS)
  60 AC_SUBST(XEXT_LIBS)
  61
  62 # Check GTK+ 3.0
  63 PKG_CHECK_MODULES(GTK,
  64                   [gtk+-3.0 >= 3.4],,
  65                   [AC_MSG_WARN("gtk missing psensor will not be built")])
  66 AM_CONDITIONAL(GTK, test -n "$GTK_LIBS")
  67 # ensure that only allowed headers are included
  68 GTK_CFLAGS+=" -DGTK_DISABLE_SINGLE_INCLUDES "
  69 # ensure that no gtk deprecated symbols are used
  70 GTK_CFLAGS+=" -DGDK_DISABLE_DEPRECATED "
  71 GTK_CFLAGS+=" -DGTK_DISABLE_DEPRECATED "
  72 # ensure use of accessors
  73 GTK_CFLAGS+=" -DGSEAL_ENABLE "
  74 AC_SUBST(GTK_CFLAGS)
  75 AC_SUBST(GTK_LIBS)
  76
  77 # Check udisks2
  78 PKG_CHECK_MODULES(LIBUDISKS2,
  79                   udisks2,
  80                   [AC_DEFINE([HAVE_LIBUDISKS2],[1],[Use libudisks])],
  81                   [AC_MSG_WARN("Library udisks2 not present")])
  82 AM_CONDITIONAL(LIBUDISKS2, test -n "$LIBUDISKS2_LIBS")
  83 AC_SUBST(LIBUDISKS2_CFLAGS)
  84 AC_SUBST(LIBUDISKS2_LIBS)
  85
  86 # Check libatasmart
  87 PKG_CHECK_MODULES(ATASMART, libatasmart,
  88                   [AC_DEFINE([HAVE_ATASMART],[1],[Use libatasmart])],
  89                   [AC_MSG_WARN("Library atasmart not present")])
  90
  91 AM_CONDITIONAL(ATASMART, test -n "$ATASMART_LIBS")
  92 AC_SUBST(ATASMART_CFLAGS)
  93 AC_SUBST(ATASMART_LIBS)
  94
  95 # Check libnotify
  96 LIBNOTIFY_LIBS=
  97 PKG_CHECK_MODULES(LIBNOTIFY,
  98   libnotify,
  99   [AC_DEFINE([HAVE_LIBNOTIFY],[1],[Use desktop notification])],
 100   [AC_MSG_WARN("Desktop notification disabled")])
 101 AM_CONDITIONAL(LIBNOTIFY, test -n "$LIBNOTIFY_LIBS")
 102 AC_SUBST(LIBNOTIFY_CFLAGS)
 103 AC_SUBST(LIBNOTIFY_LIBS)
 104
 105 # Checks AppIndicator
 106 APPINDICATOR_LIBS=
 107
 108 PKG_CHECK_MODULES(APPINDICATOR, appindicator3-0.1,
 109      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator3-0.1])],
 110      [AC_MSG_WARN(AppIndicator 3-0.1 not present")])
 111
 112 if test "$APPINDICATOR_LIBS" == ""; then
 113    PKG_CHECK_MODULES(APPINDICATOR,
 114      appindicator-0.1 <= 0.2.9 ,
 115      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator 0.2.9])
 116       AC_DEFINE([HAVE_APPINDICATOR_029],[1],[Use AppIndicator 0.2.9])
 117      ],
 118      [AC_MSG_WARN(AppIndicator 0.2.9 not present")])
 119 fi
 120
 121 if test "$APPINDICATOR_LIBS" == ""; then
 122    PKG_CHECK_MODULES(APPINDICATOR,
 123      appindicator-0.1 > 0.2.9,
 124      [AC_DEFINE([HAVE_APPINDICATOR],[1],[Use AppIndicator > 0.2.9])],
 125      [AC_MSG_WARN("AppIndicator > 0.2.9 not present")])
 126 fi
 127 AM_CONDITIONAL(APPINDICATOR, test -n "$APPINDICATOR_LIBS")
 128 AC_SUBST(APPINDICATOR_CFLAGS)
 129 AC_SUBST(APPINDICATOR_LIBS)
 130
 131 # Check CURL, needed for remote monitoring
 132 CURL_LIBS=
 133 PKG_CHECK_MODULES(CURL,
 134   libcurl,
 135   [AC_DEFINE([HAVE_CURL],[1],[Use CURL])],
 136   [AC_MSG_WARN("Remote monitoring disabled, curl missing")])
 137 AM_CONDITIONAL(CURL, test -n "$CURL_LIBS")
 138 AC_SUBST(CURL_CFLAGS)
 139 AC_SUBST(CURL_LIBS)
 140
 141 # Check JSON, needed for remote monitoring
 142 JSON_LIBS=
 143 PKG_CHECK_MODULES(JSON,
 144                   json-c >= 0.11.99,
 145                   [AC_DEFINE([HAVE_JSON],[1],[Use JSON])],
 146                   [AC_MSG_WARN("json-c missing")])
 147
 148 if test "$JSON_LIBS" == ""; then
 149 PKG_CHECK_MODULES(JSON,
 150                   json >= 0.11.99,
 151                   [AC_DEFINE([HAVE_JSON],[1],[Use JSON])
 152                    AC_DEFINE([HAVE_JSON_0],[1],[Use JSON0])],
 153                   [AC_MSG_WARN("json0 missing")])
 154 fi
 155
 156 AM_CONDITIONAL(JSON, test -n "$JSON_LIBS")
 157 AC_SUBST(JSON_CFLAGS)
 158 AC_SUBST(JSON_LIBS)
 159
 160 # Enables remote monitoring if JSON and CURL is present
 161 if test -n "$JSON_LIBS"; then
 162    if test -n "$CURL_LIBS"; then
 163    AC_DEFINE([HAVE_REMOTE_SUPPORT],[1],[Remote monitoring enabled])
 164    fi
 165 fi
 166
 167 # Checks NVIDIA
 168 # following code from sensors-applet
 169 # sensors-applet.sourceforge.net/
 170 AC_CHECK_HEADERS(NVCtrl/NVCtrl.h NVCtrl/NVCtrlLib.h,
 171                  [ HAVE_NVIDIA=true ], [],
 172                  [
 173                   #include <X11/Xlib.h>
 174                  ])
 175 if test -n "${X11_LIBS}"; then
 176 LIBS="${LIBS} -lX11 -lXext"
 177
 178 if test "${HAVE_NVIDIA}" = "true"; then
 179   AC_CHECK_LIB(XNVCtrl,XNVCTRLQueryExtension,
 180                  [NVIDIA_LIBS="-lXNVCtrl -lX11 -lXext"
 181                   AC_DEFINE(HAVE_NVIDIA,1,[NVidia support enabled])
 182                  ])
 183 fi
 184 fi
 185 AM_CONDITIONAL(NVIDIA, test -n "$NVIDIA_LIBS")
 186 AC_SUBST(NVIDIA_CFLAGS)
 187 AC_SUBST(NVIDIA_LIBS)
 188
 189 # Checks Unity
 190 PKG_CHECK_MODULES(UNITY,
 191                   unity >= 3.4.2,
 192                   [AC_DEFINE([HAVE_UNITY],[1],[Use Unity])],
 193                   [AC_MSG_WARN(Unity not present)])
 194 AC_SUBST(UNITY_CFLAGS)
 195 AC_SUBST(UNITY_LIBS)
 196 AM_CONDITIONAL(UNITY, test -n "$UNITY_LIBS")
 197
 198 # Check libatiadl
 199 AC_ARG_WITH(libatiadl,
 200 [  --with-libatiadl[=DIR]   use libatiadlxx in DIR],[
 201                    ATIADL_DIR=${withval}
 202                    CPPFLAGS="${CPPFLAGS} -I${ATIADL_DIR}/include"
 203                    LIBS="$LIBS -L/usr/lib/fglrx -L/usr/lib64/fglrx -L/usr/lib/catalyst -L/usr/lib64/catalyst"
 204                   ]
 205 )
 206
 207 AC_CHECK_HEADERS(adl_defines.h,
 208         AC_CHECK_LIB(atiadlxx,ADL_Main_Control_Refresh,
 209                 [
 210                         AC_DEFINE(HAVE_LIBATIADL,1,[libatiadl is available])
 211                         LIBATIADL_CFLAGS="-I${ATIADL_DIR}/include"
 212                         LIBATIADL_LIBS="-L/usr/lib/fglrx -L/usr/lib64/fglrx -L/usr/lib/catalyst -L/usr/lib64/catalyst -latiadlxx -ldl"
 213                 ]))
 214
 215 AM_CONDITIONAL(LIBATIADL, test -n "$LIBATIADL_LIBS")
 216 AC_SUBST(LIBATIADL_CFLAGS)
 217 AC_SUBST(LIBATIADL_LIBS)
 218
 219 ############### psensor-server
 220
 221 # Check libmicrohttpd, mandatory for psensor-server
 222 LIBMICROHTTPD_LIBS=
 223 PKG_CHECK_MODULES(LIBMICROHTTPD,
 224   libmicrohttpd,
 225   [AC_DEFINE([HAVE_LIBMICROHTTPD],[1],[Use libmicrohttpd])],
 226   [AC_MSG_WARN("libmicrohttpd not present, psensor-server will NOT be built")])
 227 AM_CONDITIONAL(LIBMICROHTTPD, test -n "$LIBMICROHTTPD_LIBS")
 228 AC_SUBST(LIBMICROHTTPD_CFLAGS)
 229 AC_SUBST(LIBMICROHTTPD_LIBS)
 230
 231 # Check gtop2, optional
 232 AC_ARG_WITH(gtop,
 233 [  --with-gtop[=yes|no]   use gtop],[
 234         with_gtop=$withval],[
 235         with_gtop="yes"
 236 ])
 237
 238 GTOP_LIBS=
 239 if test "$with_gtop" = "yes"; then
 240 PKG_CHECK_MODULES(GTOP,
 241   libgtop-2.0,
 242   [AC_DEFINE([HAVE_GTOP],[1],[Use GTOP])],
 243   [AC_MSG_WARN("gtop not present, CPU/Memory information will NOT be available")])
 244 fi
 245 AM_CONDITIONAL(GTOP, test -n "$GTOP_LIBS")
 246 AC_SUBST(GTOP_CFLAGS)
 247 AC_SUBST(GTOP_LIBS)
 248
 249 AC_CONFIG_FILES([
 250  Makefile
 251  doc/Makefile
 252  src/Makefile
 253  src/glade/Makefile
 254  src/lib/Makefile
 255  src/server/Makefile
 256  icons/hicolor/scalable/Makefile
 257  icons/hicolor/14x14/Makefile
 258  icons/hicolor/16x16/Makefile
 259  icons/hicolor/22x22/Makefile
 260  icons/hicolor/24x24/Makefile
 261  icons/hicolor/32x32/Makefile
 262  icons/hicolor/48x48/Makefile
 263  icons/hicolor/64x64/Makefile
 264  icons/ubuntu-mono-dark/status/22/Makefile
 265  icons/ubuntu-mono-light/status/22/Makefile
 266  icons/ubuntu-mono-dark/apps/22/Makefile
 267  www/Makefile
 268  po/Makefile.in
 269  tests/Makefile
 270 ])
 271
 272 AC_CHECK_PROGS([HELP2MAN], [help2man])
 273
 274 AC_CHECK_PROG([ASCIIDOC], [asciidoc], yes)
 275 AM_CONDITIONAL(ASCIIDOC, test -n "$ASCIIDOC")
 276
 277 AC_CHECK_PROG(HAVE_CPPCHECK, cppcheck, yes)
 278 AM_CONDITIONAL(CPPCHECK, test -n "$HAVE_CPPCHECK")
 279
 280 AC_OUTPUT